1  # Maintainer: Thule <vincenzo.frascino@proton.me>
 2  # Contributor: Neptune <neptune650@proton.me>
 3  # Contributor: Sergej Pupykin <pupykin.s+arch@gmail.com>
 4  # Contributor: Dag Odenhall <dag.odenhall@gmail.com>
 5  # Contributor: Grigorios Bouzakis <grbzks@gmail.com>
 6  
 7  pkgname=dwm
 8  pkgver=6.8
 9  pkgrel=3
10  pkgdesc="A dynamic window manager for X"
11  url="https://dwm.suckless.org"
12  arch=('i686' 'x86_64' 'arm' 'armv7h' 'armv6h' 'aarch64')
13  license=('MIT')
14  options=(zipman)
15  depends=('libx11' 'libxinerama' 'libxft' 'freetype2')
16  install=dwm.install
17  source=(dwm.desktop
18          https://dl.suckless.org/dwm/dwm-$pkgver.tar.gz
19          config.h)
20  sha256sums=('bc36426772e1471d6dd8c8aed91f288e16949e3463a9933fee6390ee0ccd3f81'
21              'bcf540589ad174d4073f4efa658828411e2f5ba63196cfaf6b71363700f590b7'
22              'SKIP')
23  
24  prepare() {
25    cd "$srcdir/$pkgname-$pkgver"
26    if [[ -f "$srcdir/config.h" ]]; then
27      cp -fv "$srcdir/config.h" config.h
28    fi
29  }
30  
31  build() {
32    cd "$srcdir/$pkgname-$pkgver"
33    make X11INC=/usr/include/X11 X11LIB=/usr/lib/X11 FREETYPEINC=/usr/include/freetype2
34  }
35  
36  package() {
37    cd "$srcdir/$pkgname-$pkgver"
38    make PREFIX=/usr DESTDIR="$pkgdir" install
39    install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
40    install -Dm644 README "$pkgdir/usr/share/doc/$pkgname/README"
41    install -Dm644 "$srcdir/dwm.desktop" "$pkgdir/usr/share/xsessions/dwm.desktop"
42  }