1  # Maintainer: Dominik Nakamura <dnaka91@gmail.com>
 2  # https://github.com/dnaka91/pkgbuilds
 3  
 4  pkgname=ffprog
 5  pkgver=0.1.3
 6  pkgrel=2
 7  pkgdesc="FFmpeg with nice progress visualization"
 8  arch=('aarch64' 'i686' 'x86_64')
 9  url="https://github.com/dnaka91/ffprog"
10  license=('AGPL-3.0-only')
11  depends=('ffmpeg' 'gcc-libs')
12  makedepends=('cargo')
13  source=("$pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")
14  b2sums=('bccaa1e31fc82e8c2eb6d16eea6055512311055518aae9cd24236d729d7c119211a4f085ca68326cef9cfb6dcb2cb4dbb5db6f196e39cd98bc9eb6cc5f749488')
15  
16  prepare() {
17    cd "$pkgname-$pkgver"
18    cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
19  }
20  
21  build() {
22    cd "$pkgname-$pkgver"
23    export RUSTUP_TOOLCHAIN=stable
24    export CARGO_TARGET_DIR=target
25    cargo build --frozen --release --all-features
26  }
27  
28  check() {
29    cd "$pkgname-$pkgver"
30    export RUSTUP_TOOLCHAIN=stable
31    cargo test --frozen --all-features
32  }
33  
34  package() {
35    cd "$pkgname-$pkgver"
36    install -Dm 755 target/release/"$pkgname" -t "$pkgdir"/usr/bin
37    install -Dm 644 LICENSE -t "$pkgdir"/usr/share/licenses/"$pkgname"
38    install -Dm 644 README.md -t "$pkgdir"/usr/share/doc/"$pkgname"
39  
40    install -dm 755 "$pkgdir"/usr/share/{bash-completion/completions,fish/vendor_completions.d,zsh/site-functions}/
41    ./target/release/"$pkgname" completions bash > "$pkgdir"/usr/share/bash-completion/completions/"$pkgname"
42    ./target/release/"$pkgname" completions fish > "$pkgdir"/usr/share/fish/vendor_completions.d/"$pkgname".fish
43    ./target/release/"$pkgname" completions zsh > "$pkgdir"/usr/share/zsh/site-functions/_"$pkgname"
44  
45    install -dm 755 "$pkgdir"/usr/share/man/man1/
46    ./target/release/"$pkgname" manpages "$pkgdir"/usr/share/man/man1
47  }