1  $       ! Packaging OpenSSL into an install kit
 2  $       !
 3  $       ! P1 - OpenSSL source directory
 4  $       !
 5  $       ! This command procedure will create two subdirectories,
 6  $       ! [._build_'arch'] and [._kit_'arch'].  [._build_'arch']
 7  $	! is used for OpenSSL builds, and [._kit_'arch'] is used
 8  $	! to build up the final kit.
 9  $
10  $       ! Find the architecture
11  $       IF F$GETSYI("CPU") .LT. 128
12  $       THEN
13  $           arch := VAX
14  $       ELSE
15  $           arch = F$EDIT(F$GETSYI("ARCH_NAME"),"UPCASE")
16  $           IF arch .EQS. "" THEN GOTO unknown_arch
17  $       ENDIF
18  $       name_Alpha := AXPVMS
19  $       name_IA64  := I64VMS
20  $       name_VAX   := VAXVMS
21  $       arch = name_'arch'
22  $
23  $       ON ERROR THEN GOTO end
24  $       ON CONTROL_Y THEN GOTO end
25  $
26  $       source = F$PARSE("A.;", P1, "[]") - "]A.;"
27  $       here = F$ENVIRONMENT("DEFAULT") - "]"
28  $
29  $       SET DEFAULT 'source']
30  $       SET DEFAULT [.util]
31  $       util = F$ENVIRONMENT("DEFAULT") - "]"
32  $       SET DEFAULT 'here']
33  $
34  $       CREATE/DIR [._build_'arch']
35  $       CREATE/DIR [._kit_'arch']
36  $       CREATE/DIR [._kit_'arch'.files]
37  $
38  $       SET DEFAULT [._kit_'arch']
39  $       kit = F$ENVIRONMENT("DEFAULT") - "]"
40  $
41  $       SET DEFAULT [-._build_'arch']
42  $       build = F$ENVIRONMENT("DEFAULT")
43  $
44  $       @'source']config -32 shared
45  $       MMS build_libs,install_dev /mac=destdir='kit'.files]
46  $
47  $       MMS clean
48  $       @'source']config -64 shared
49  $       MMS build_libs,install_dev /mac=destdir='kit'.files]
50  $
51  $       MMS clean
52  $       @'source']config shared
53  $       MMS all,install /mac=destdir='kit'.files]
54  $
55  $       purge 'kit'.files...]*.*
56  $
57  $       SET DEFAULT [-]
58  $       perl "-I_build_''arch'" "-Mconfigdata" 'source'.util]dofile.pl -
59               openssl.pcsi$desc-in > [._kit_'arch']openssl.pcsi$desc
60  $       perl "-I_build_''arch'" "-Mconfigdata" 'source'.util]dofile.pl -
61               openssl.pcsi$text-in > [._kit_'arch']openssl.pcsi$text
62  $       perl "-I_build_''arch'" "-Mconfigdata" 'source'.util]dofile.pl -
63               ossl$startup.com.in > [._kit_'arch'.files]ossl$startup.com
64  $       perl "-I_build_''arch'" "-Mconfigdata" 'source'.util]dofile.pl -
65               ossl$utils.com.in > [._kit_'arch'.files]ossl$utils.com
66  $       perl "-I_build_''arch'" "-Mconfigdata" 'source'.util]dofile.pl -
67               ossl$shutdown.com.in > [._kit_'arch'.files]ossl$shutdown.com
68  $       perl "-I_build_''arch'" "-Mconfigdata" 'source'.util]dofile.pl -
69               ossl$ivp.com.in > [._kit_'arch'.files]ossl$ivp.com
70  $
71  $       PRODUCT PACKAGE OpenSSL -
72                  /BASE='arch' -
73                  /PRODUCER=Levitte -
74                  /SOURCE=[._kit_'arch']openssl -
75                  /DESTINATION=[._kit_'arch'] -
76                  /MATERIAL=([._kit_'arch'.files...]) -
77                  /FORMAT=SEQUENTIAL
78  $
79  $ end:
80  $       SET DEFAULT 'here']