1  #version 450
 2  
 3  #include "mul_mat_vec_base.comp"
 4  
 5  layout(local_size_x = 32, local_size_y = 1, local_size_z = 1) in;
 6  
 7  shared FLOAT_TYPE tmp[32];
 8  
 9  void main() {
10      const uint row = gl_WorkGroupID.x;
11  
12      uint a_offset, b_offset, d_offset;
13      get_offsets(a_offset, b_offset, d_offset);
14  
15      const uint num_blocks_per_row = p.ncols / QUANT_K;
16      const uint ib0 = a_offset / QUANT_K + row*num_blocks_per_row;
17  
18      const uint tid = gl_LocalInvocationID.x/K_QUANTS_PER_ITERATION;  // 0...31 or 0...16
19      const uint ix  = gl_LocalInvocationID.x%K_QUANTS_PER_ITERATION;  // 0 or 0, 1
20  
21      const uint step = 16/K_QUANTS_PER_ITERATION;            // 16 or 8
22  
23      const uint v_im = tid/step;                             // 0 or 1. 0 computes 0..., 1 computes 128...
24      const uint v_in = tid - step*v_im;                      // 0...15 or 0...7
25  
26      const uint l0 = K_QUANTS_PER_ITERATION*v_in;            // 0...15
27      const uint q_offset = 32*v_im + l0;
28      const uint s_offset = 8*v_im;
29      const uint y_offset = 128*v_im + l0;
30  
31      tmp[16 * ix + tid] = FLOAT_TYPE(0.0); // partial sum for thread in warp
32  
33      [[unroll]] for (uint i = ix; i < num_blocks_per_row; i += K_QUANTS_PER_ITERATION) {
34          const uint y_idx = i * QUANT_K + y_offset;
35  
36          const FLOAT_TYPE dall = FLOAT_TYPE(data_a[ib0 + i].d.x);
37          const FLOAT_TYPE dmin = FLOAT_TYPE(data_a[ib0 + i].d.y);
38  
39          FLOAT_TYPE sum1 = FLOAT_TYPE(0.0);
40          FLOAT_TYPE sum2 = FLOAT_TYPE(0.0);
41          for (int l = 0; l < K_QUANTS_PER_ITERATION; ++l) {
42              sum1 += FLOAT_TYPE(data_b[b_offset + y_idx + l +  0]) * FLOAT_TYPE(data_a[ib0 + i].scales[s_offset + 0] & 0xF) * FLOAT_TYPE((data_a[ib0 + i].qs[q_offset + l + 0] >> 0) & 3)
43                    + FLOAT_TYPE(data_b[b_offset + y_idx + l + 16]) * FLOAT_TYPE(data_a[ib0 + i].scales[s_offset + 1] & 0xF) * FLOAT_TYPE((data_a[ib0 + i].qs[q_offset + l +16] >> 0) & 3)
44                    + FLOAT_TYPE(data_b[b_offset + y_idx + l + 32]) * FLOAT_TYPE(data_a[ib0 + i].scales[s_offset + 2] & 0xF) * FLOAT_TYPE((data_a[ib0 + i].qs[q_offset + l + 0] >> 2) & 3)
45                    + FLOAT_TYPE(data_b[b_offset + y_idx + l + 48]) * FLOAT_TYPE(data_a[ib0 + i].scales[s_offset + 3] & 0xF) * FLOAT_TYPE((data_a[ib0 + i].qs[q_offset + l +16] >> 2) & 3)
46                    + FLOAT_TYPE(data_b[b_offset + y_idx + l + 64]) * FLOAT_TYPE(data_a[ib0 + i].scales[s_offset + 4] & 0xF) * FLOAT_TYPE((data_a[ib0 + i].qs[q_offset + l + 0] >> 4) & 3)
47                    + FLOAT_TYPE(data_b[b_offset + y_idx + l + 80]) * FLOAT_TYPE(data_a[ib0 + i].scales[s_offset + 5] & 0xF) * FLOAT_TYPE((data_a[ib0 + i].qs[q_offset + l +16] >> 4) & 3)
48                    + FLOAT_TYPE(data_b[b_offset + y_idx + l + 96]) * FLOAT_TYPE(data_a[ib0 + i].scales[s_offset + 6] & 0xF) * FLOAT_TYPE((data_a[ib0 + i].qs[q_offset + l + 0] >> 6) & 3)
49                    + FLOAT_TYPE(data_b[b_offset + y_idx + l +112]) * FLOAT_TYPE(data_a[ib0 + i].scales[s_offset + 7] & 0xF) * FLOAT_TYPE((data_a[ib0 + i].qs[q_offset + l +16] >> 6) & 3);
50              sum2 += FLOAT_TYPE(data_b[b_offset + y_idx + l +  0]) * FLOAT_TYPE((data_a[ib0 + i].scales[s_offset + 0] >> 4) & 0xF)
51                    + FLOAT_TYPE(data_b[b_offset + y_idx + l + 16]) * FLOAT_TYPE((data_a[ib0 + i].scales[s_offset + 1] >> 4) & 0xF)
52                    + FLOAT_TYPE(data_b[b_offset + y_idx + l + 32]) * FLOAT_TYPE((data_a[ib0 + i].scales[s_offset + 2] >> 4) & 0xF)
53                    + FLOAT_TYPE(data_b[b_offset + y_idx + l + 48]) * FLOAT_TYPE((data_a[ib0 + i].scales[s_offset + 3] >> 4) & 0xF)
54                    + FLOAT_TYPE(data_b[b_offset + y_idx + l + 64]) * FLOAT_TYPE((data_a[ib0 + i].scales[s_offset + 4] >> 4) & 0xF)
55                    + FLOAT_TYPE(data_b[b_offset + y_idx + l + 80]) * FLOAT_TYPE((data_a[ib0 + i].scales[s_offset + 5] >> 4) & 0xF)
56                    + FLOAT_TYPE(data_b[b_offset + y_idx + l + 96]) * FLOAT_TYPE((data_a[ib0 + i].scales[s_offset + 6] >> 4) & 0xF)
57                    + FLOAT_TYPE(data_b[b_offset + y_idx + l +112]) * FLOAT_TYPE((data_a[ib0 + i].scales[s_offset + 7] >> 4) & 0xF);
58          }
59          tmp[16 * ix + tid] += dall * sum1 - dmin * sum2;
60      }
61  
62      // sum up partial sums and write back result
63      barrier();
64      [[unroll]] for (uint s = 16; s > 0; s >>= 1) {
65          if (tid < s) {
66              tmp[tid] += tmp[tid + s];
67          }
68          barrier();
69      }
70      if (tid == 0) {
71          data_d[d_offset + row] = D_TYPE(tmp[0]);
72      }
73  }