1  #version 450
 2  
 3  #include "generic_head.comp"
 4  #include "types.comp"
 5  
 6  #extension GL_EXT_control_flow_attributes : enable
 7  #define BLOCK_SIZE 512
 8  
 9  layout(local_size_x = BLOCK_SIZE, local_size_y = 1, local_size_z = 1) in;
10  
11  layout (binding = 0) readonly buffer X {A_TYPE data_a[];};
12  layout (binding = 1) writeonly buffer D {D_TYPE data_d[];};
13  
14  shared vec2 sum[BLOCK_SIZE];
15  
16  void main() {
17      const uint row = gl_WorkGroupID.x;
18      const uint tid = gl_LocalInvocationID.x;
19  
20      sum[tid] = vec2(0.0f, 0.0f);
21  
22      [[unroll]] for (uint col = tid; col < p.KX; col += BLOCK_SIZE) {
23          const float xi = float(data_a[row*p.KX + col]);
24          sum[tid].x += xi;
25          sum[tid].y += xi * xi;
26      }
27  
28      // sum up partial sums and write back result
29      barrier();
30      [[unroll]] for (int s = BLOCK_SIZE / 2; s > 0; s >>= 1) {
31          if (tid < s) {
32              sum[tid] += sum[tid + s];
33          }
34          barrier();
35      }
36  
37      const float mean = sum[0].x / p.KX;
38      const float var = sum[0].y / p.KX - mean * mean;
39      const float inv_std = inversesqrt(var + p.param1);
40  
41      [[unroll]] for (uint col = tid; col < p.KX; col += BLOCK_SIZE) {
42          data_d[row*p.KX + col] = D_TYPE((float(data_a[row*p.KX + col]) - mean) * inv_std);
43      }
44  }