1  #version 450
 2  
 3  #include "generic_head.comp"
 4  #include "types.comp"
 5  
 6  #extension GL_EXT_control_flow_attributes : enable
 7  #define BLOCK_SIZE 512
 8  
 9  layout(local_size_x = BLOCK_SIZE, local_size_y = 1, local_size_z = 1) in;
10  
11  layout (binding = 0) readonly buffer X {A_TYPE data_a[];};
12  layout (binding = 1) writeonly buffer D {D_TYPE data_d[];};
13  
14  shared FLOAT_TYPE sum[BLOCK_SIZE];
15  
16  void main() {
17      const uint row = gl_WorkGroupID.x;
18      const uint tid = gl_LocalInvocationID.x;
19  
20      sum[tid] = FLOAT_TYPE(0.0f); // partial sum for thread in warp
21  
22      [[unroll]] for (uint col = tid; col < p.KX; col += BLOCK_SIZE) {
23          const FLOAT_TYPE xi = FLOAT_TYPE(data_a[row*p.KX + col]);
24          sum[tid] += xi * xi;
25      }
26  
27      // sum up partial sums and write back result
28      barrier();
29      [[unroll]] for (int s = BLOCK_SIZE / 2; s > 0; s >>= 1) {
30          if (tid < s) {
31              sum[tid] += sum[tid + s];
32          }
33          barrier();
34      }
35  
36      const FLOAT_TYPE mean = sum[0] / FLOAT_TYPE(p.KX);
37      const FLOAT_TYPE scale = inversesqrt(mean + FLOAT_TYPE(p.param1));
38  
39      [[unroll]] for (uint col = tid; col < p.KX; col += BLOCK_SIZE) {
40          data_d[row*p.KX + col] = D_TYPE(scale * FLOAT_TYPE(data_a[row*p.KX + col]));
41      }
42  }